home *** CD-ROM | disk | FTP | other *** search
/ Technotools / Technotools (Chestnut CD-ROM)(1993).ISO / lang_asm / asm_kit / tee1.asm < prev    next >
Assembly Source File  |  1985-08-28  |  3KB  |  139 lines
  1.     name    tee
  2.     page    55,132
  3.     title    'TEE - tee junction for DOS pipes'
  4. ;
  5. ; TEE --- A "tee" junction for DOS 2.x pipes
  6. ;         after the fashion of the Unix function TEE  
  7. ; 
  8. ; By A. K. Head, 6 Duffryn Place, Melbourne, Australia 3142
  9. ;    Somewhat overhauled & with error handling added by Ray Duncan
  10. ;
  11. ; TEE reads from the standard input (redirectable) and
  12. ; outputs to both the standard output (redirectable)
  13. ; and a file, e.g.:   DIR | TEE C:\MYDIR\FILE.EXT | SORT
  14. ;
  15. ; The file can be CON, LPT1, etc.  If it is CON, then
  16. ; keyboard Control-S pauses the display as usual.
  17.  
  18. command    equ    80h        ; buffer for command tail
  19. buflen    equ    16384        ; buffer length, alter to taste
  20.  
  21. cr    equ    0dh        ; ASCII carriage return
  22. lf    equ    0ah        ; ASCII line feed
  23. ff    equ    0ch        ; ASCII form feed
  24. eof    equ    01ah        ; End-of-file marker
  25. tab    equ    09h        ; ASCII tab code
  26. blank    equ    20h        ; ASCII blank
  27.  
  28.                 ; DOS 2.x pre-defined handles
  29. stdin    equ    0000        ; standard input file
  30. stdout    equ    0001        ; standard output file
  31. stderr    equ    0002        ; standard error file
  32. stdaux    equ    0003        ; standard auxilliary file
  33. stdprn    equ    0004        ; standard printer file
  34.  
  35.  
  36. cseg    segment para public 'CODE'
  37.  
  38.     assume    cs:cseg,ds:cseg
  39.  
  40.     org    100H        ; start .COM at 100H
  41.  
  42. tee    proc    far
  43.  
  44.     mov    cl,ds:command     ; get length of command tail.
  45.     xor    ch,ch 
  46.                 ; address of command string.
  47.     mov    si,offset command+1 
  48.     mov    di,offset command+1
  49.  
  50. tee1:                ; squeeze out leading spaces.
  51.     mov    al,byte ptr [si]
  52.     cmp    al,blank
  53.     jbe    tee2
  54.     mov    byte ptr [di],al
  55.     inc    di
  56.  
  57. tee2:    inc    si        ; look through command tail
  58.     loop    tee1        ; until it's exhausted.
  59.     mov    byte ptr [di],0 ; make ASCIIZ string.
  60.     mov    ah,3ch        ; create output file.
  61.     mov    cx,0        ; attribute=0.
  62.     mov    dx,offset command+1
  63.     int    21h
  64.     jc    tee6        ; can't create file
  65.     mov    handle,ax    ; save token for file.
  66.  
  67. tee3:    mov    ah,3fh        ; read standard input.
  68.     mov    bx,stdin
  69.     mov    cx,buflen
  70.     lea    dx,buffer
  71.     int    21h
  72.     jc    tee4        ; jump, error.
  73.     mov    nchar,ax    ; save length of read.
  74.     cmp    ax,0        ; nothing read in?
  75.     je    tee4        ; end of file, exit.
  76.     mov    ah,40h        ; write to file...
  77.     mov    bx,handle
  78.     mov    cx,nchar
  79.     int    21h
  80.     jc    tee7        ; jump, write failed.
  81.     cmp    ax,nchar
  82.     jne    tee7        ; jump, write failed.
  83.     mov    ah,40h        ; now write to standard output...
  84.     mov    bx,stdout
  85.     int    21h
  86.     jc    tee7        ; jump, write failed.
  87.     cmp    ax,nchar
  88.     jne    tee7        ; jump, write failed.
  89.     jmp     tee3        ; read again until end of file.
  90.  
  91. tee4:    mov    ah,3eh        ; close output file.
  92.     mov    bx,handle
  93.     int    21h
  94.  
  95. tee5:    mov    ax,4c00h    ; exit with return code=0.
  96.     int    21h
  97.  
  98. tee6:    mov    dx,offset err1    ; print "Can't create file".
  99.     mov    cx,err1len
  100.          mov    ah,40h        ; display error message and exit.
  101.     mov    bx,stderr
  102.     int    21h
  103.     mov    ax,4c01h    ; exit with return code=1.
  104.     int    21h
  105.  
  106. tee7:    mov    dx,offset err2    ; print "Disk is full".
  107.     mov    cx,err2len
  108.          mov    ah,40h        ; display error message and exit.
  109.     mov    bx,stderr
  110.     int    21h
  111.     mov    ah,3eh        ; close output file.
  112.     mov    bx,handle
  113.     int    21h
  114.     mov    ax,4c02h    ; exit with return code=2.
  115.     int    21h
  116.  
  117. tee    endp
  118.  
  119.  
  120. nchar    dw     0        ; number of chars actually input.
  121. handle    dw    0        ; token for output file.
  122.  
  123. err1       db    cr,lf
  124.     db    'tee: Cannot create file' 
  125.     db    cr,lf
  126. err1len equ    (this byte)-(offset err1) 
  127.  
  128. err2     db    cr,lf
  129.     db    'tee: Disk is full.'
  130.     db    cr,lf
  131. err2len equ    (this byte)-(offset err2) 
  132.  
  133. buffer    equ    this byte    ; data is read here from
  134.                 ; standard input
  135.  
  136. cseg    ends
  137.  
  138.     end    tee
  139.